Amiga Collections: Nordlicht Spiele/Nordlicht Spiele 25-02 (19xx)(Nordlicht)(DE)(PD).zip/Nordlicht Spiele 25-02 (19xx)(Nordlicht)(DE)(PD).adf/Kreuzweg/kreuzweg/kreuzweg.amosSourceCode

AMOS Source Code | 1993-02-04 | 18KB | 705 lines

' *************************
' *    Version 26.1.92    *
' *          25er         *
' *************************
'
Hide
Screen Open 0,640,256,16,Hires
Unpack 6 To 0
Repeat
Until Mouse Key
Screen Close 0
Screen Open 1,320,256,32,Lowres
If Exist("df1:Kreuzweg/check")
   Dir$="df1:Kreuzweg/"
Else
   Dir$="df0:Kreuzweg/"
End If
Unpack 5 To 1
Show
'
Dim ANZAHL(11),ZEIGEFLAG(11),NORD(31),OST(31),SUED(31),WEST(31),GESETZTFLAG(46)
Dim OFFEN(3,4)
Global ANZAHL(),ZEIGEFLAG(),NORD(),OST(),SUED(),WEST(),GESETZTFLAG(),PASSEN
Global NUMMER,LEVEL,GELOEST,OK,KONTROLLZAEHLER,AUS_STREET,LOESEFLAG,MENGE,GEHT
Global OFFEN()
INITIAL
'
'...................................
'.          HAUPTPROGRAMM          .
'...................................
'
LEVEL=1
MENGE=25
Curs Off
Flash Off
Double Buffer
Autoback 0
Update Off
'
EINLESEN
LOSUNG[EINGABE$]
'
HAUPT:
Repeat
   GEHT=0
   If GELOEST=-1
      DUM=Free
      Shoot
      GRATULATION
      NEUER_VERSUCH
      EINLESEN
      LOSUNG[EINGABE$]
      If LEVEL=6 or LEVEL=11 or LEVEL=16 or LEVEL=21
         LESEN=0
      End If
      UNDO_STREET=0
      GELOEST=0
      BEGINN=0
   End If
   If LEVEL<6 and LESEN=0
      Load "streets.abk"
      LESEN=-1
   End If
   If LEVEL>5 and LEVEL<11 and LESEN=0
      Load "city.abk"
      LESEN=-1
   End If
   If LEVEL>10 and LEVEL<16 and LESEN=0
      Load "fluss.abk"
      LESEN=-1
   End If
   If LEVEL>15 and LEVEL<21 and LESEN=0
      Load "color.abk"
      LESEN=-1
   End If
   If LEVEL>20 and LEVEL<26 and LESEN=0
      Load "spiel.abk"
      LESEN=-1
   End If
   Z=Mouse Zone
   '
   If Z=44 and BEGINN=0 and Mouse Key
      Bell
      PASSWORD
      If Param=-1
         EINLESEN
         LESEN=0
      End If
   End If
   '
   If Z=45 and BEGINN=0 and Mouse Key
      INFO
   End If
   '
   If Z>30 and Z<44 and Mouse Key
      BEGINN=-1
      If Z<42
         STREET=Z-30
         Screen Swap : DRUECKEN[29,19,-11+(19*STREET),5+(19*STREET),198,214]
         Screen Swap : DRUECKEN[29,19,-11+(19*STREET),5+(19*STREET),198,214]
      End If
      If Z=42
         Goto WEITER
      End If
      If Z=43
         Goto UNDO
      End If
      If ANZAHL(STREET)>0
         Bell
         WERT_NEHMEN[Z]
         Dec ANZAHL(STREET) : AUSGABE : LOESEN
         Inc NUMMER
         Hot Spot STREET,$11
         SCHLEIFE:
         Do
            Z=Mouse Zone
            Screen Swap : Wait Vbl : Bob Clear
            Bob NUMMER,X Screen(X Mouse),Y Screen(Y Mouse),STREET
            Bob Draw
            Screen Swap : Wait Vbl : Bob Clear
            Bob NUMMER,X Screen(X Mouse),Y Screen(Y Mouse),STREET
            Bob Draw
            If Z=42 and Mouse Key
               Goto WEITER
            End If
            If Z>0 and Z<31 and GESETZTFLAG(Z)=0 and Mouse Key
               PRUEF=Z
               PRUEFEN[Z]
               Exit If OK=2 or GEHT=0
               Hot Spot STREET,$0
               I=Abs(Z/6)
               J=Z-(I*6)
               If J=0
                  J=6 : I=I-1
               End If
               X=-25+(34*J) : Y=20+(34*I)
               Screen Swap : Wait Vbl : Bob Clear
               Bob NUMMER,X,Y,STREET : Bob Draw
               Screen Swap : Wait Vbl : Bob Clear
               Bob NUMMER,X,Y,STREET : Bob Draw
               GESETZTFLAG(Z)=-1
               WERT_GEBEN[Z]
               OK=0
               ENTFERNT=Z
               ERLAUBT=-1
               UNDO_STREET=STREET
               Exit
            End If
         Loop
      Else
         Wave 0 To %1100 : Play 46,0
         Goto HAUPT
      End If
      '
      If OK<>0 or GEHT=0
         Bell
         WERTE_ZURUECK[Z]
         Goto SCHLEIFE
      End If
      '
      WEITER:
      OK=0
      KONTROLLZAEHLER=0
      If Z=42 and Mouse Key
         NOCHMAL_VON_VORN
      End If
      '
      UNDO:
      If Z=43 and ERLAUBT=-1 and Mouse Key
         ZULETZT_ERNEUT[ENTFERNT,UNDO_STREET]
         ERLAUBT=0
      End If
      '
   End If
   If STREET>0
      Screen Swap : DRUECKEN[19,29,-11+(19*STREET),5+(19*STREET),198,214]
      Screen Swap : DRUECKEN[19,29,-11+(19*STREET),5+(19*STREET),198,214]
   End If
   If LEVEL>MENGE and GELOEST=-1
      SPIELENDE=-1
      Exit
   End If
Until Z=46 and Mouse Key
'
If SPIELENDE=0
   SICHERHEITSABFRAGE
   If Param=2
      Goto HAUPT
   End If
End If
Erase 1
Screen Swap : Locate ,30 : Centre "Game over"
Screen Swap : Locate ,30 : Centre "Game over"
Wait 200
Screen Close 1
Edit
'
' ------------------------------
' |         ROUTINEN           |
' ------------------------------
'
Procedure INITIAL
   Reserve Zone 46
   For I=1 To 5
      For J=1 To 6
         Inc Z
         Set Zone Z,-25+(34*J),-14+(34*I) To 7+(34*J),18+(34*I)
      Next J
   Next I
   For I=1 To 11
      Inc Z
      Set Zone Z,-10+(19*I),199 To 5+(19*I),214
   Next I
   Set Zone 42,235,199 To 274,214
   Set Zone 46,277,199 To 309,214
   Set Zone 43,216,199 To 232,214
   Set Zone 44,234,80 To 309,94
   Set Zone 45,235,176 To 308,189
End Proc
'
Procedure EINLESEN
   Restore LEVEL*1
   Boom
   Read LEVEL
   For I=1 To 11
      ZEIGEFLAG(I)=0
      Read ANZAHL(I)
      If ANZAHL(I)>0
         ZEIGEFLAG(I)=-1
      End If
   Next I
   Ink 20
   Screen Swap : Bar 290,60 To 308,72
   Screen Swap : Bar 290,60 To 308,72
   Screen Swap : Wait Vbl : Ink 0,20 : Text 290,69,Mid$(Str$(LEVEL),2,2)
   Screen Swap : Wait Vbl : Ink 0,20 : Text 290,69,Mid$(Str$(LEVEL),2,2)
   AUSGABE
   1 Data 1,0,1,1,1,1,1,1,0,0,0,0,0
   2 Data 2,1,2,1,1,2,0,0,0,0,0,2,0
   3 Data 3,0,1,1,2,1,1,0,1,0,1,0,0
   4 Data 4,0,1,2,2,1,1,1,0,0,0,0,0
   5 Data 5,0,2,1,1,2,0,0,1,1,2,1,0
   6 Data 6,1,2,1,1,2,0,0,1,1,0,1,0
   7 Data 7,0,1,2,2,1,1,1,1,1,0,0,0
   8 Data 8,1,1,1,1,2,1,2,1,0,1,0,0
   9 Data 9,0,2,2,1,2,1,2,0,1,0,0,0
   10 Data 10,1,2,2,1,1,1,1,0,2,1,0,0
   11 Data 11,0,3,2,2,2,1,0,0,1,3,0,0
   12 Data 12,1,3,2,1,2,1,1,0,2,0,0,0
   13 Data 13,1,2,1,2,1,2,0,1,1,2,1,0
   14 Data 14,2,2,2,2,2,0,0,0,0,2,2,0
   15 Data 15,1,1,2,3,1,1,0,2,1,0,1,0
   16 Data 16,1,2,2,1,2,1,2,0,1,1,1,0
   17 Data 17,1,2,1,1,1,1,0,1,2,5,1,0
   18 Data 18,0,1,2,1,2,0,2,2,2,1,1,0
   19 Data 19,0,2,2,2,1,1,0,1,2,1,4,0
   20 Data 20,1,2,1,3,2,2,0,2,0,2,0,0
   21 Data 21,0,2,2,2,2,1,1,2,2,1,3,0
   22 Data 22,1,2,2,3,3,1,1,2,0,2,2,0
   23 Data 23,2,2,3,2,2,2,3,1,2,0,0,0
   24 Data 24,2,2,2,2,2,1,1,2,2,2,2,0
   25 Data 25,1,3,2,2,3,1,1,3,3,1,0,0
End Proc
'
Procedure AUSGABE
   Ink 2,23
   For I=1 To 11
      If ANZAHL(I)>0
         Screen Swap : Wait Vbl : Text -7+(19*I),227,Right$(Str$(ANZAHL(I)),1)
         Screen Swap : Wait Vbl : Text -7+(19*I),227,Right$(Str$(ANZAHL(I)),1)
      End If
      If ANZAHL(I)=0 and ZEIGEFLAG(I)=-1
         Ink 23
         Screen Swap : Wait Vbl : Bar -9+(19*I),220 To 4+(19*I),229
         Screen Swap : Wait Vbl : Bar -9+(19*I),220 To 4+(19*I),229
         Ink 2,23
      End If
   Next I
End Proc
'
Procedure NEUER_VERSUCH
   Screen Swap : Wait Vbl : Bob Clear
   Bob Off
   Screen Swap : Wait Vbl : Bob Clear : Bob Off
   NUMMER=0
   FELDER_LOESCHEN
End Proc
'
Procedure WERT_NEHMEN[Z]
   Restore Z*1+1000
   Read NORD(31),OST(31),SUED(31),WEST(31)
   Restore Z*1+2000
   For I=1 To 4
      Read OFFEN(2,I)
      OFFEN(3,I)=0
   Next I
   1031 Data -1,-1,-1,-1
   1032 Data -1,-1,1,1
   1033 Data 1,-1,-1,1
   1034 Data -1,1,1,-1
   1035 Data 1,1,-1,-1
   1036 Data 1,-1,-1,-1
   1037 Data -1,-1,1,-1
   1038 Data -1,-1,-1,1
   1039 Data -1,1,-1,-1
   1040 Data 1,-1,1,-1
   1041 Data -1,1,-1,1
   2031 Data 1,1,1,1
   2032 Data 1,1,0,0
   2033 Data 0,1,1,0
   2034 Data 1,0,0,1
   2035 Data 0,0,1,1
   2036 Data 0,1,1,1
   2037 Data 1,1,0,1
   2038 Data 1,1,1,0
   2039 Data 1,0,1,1
   2040 Data 0,1,0,1
   2041 Data 1,0,1,0
End Proc
'
Procedure PRUEFEN[Z]
   If Z-6>0
      ERLAUBT[GESETZTFLAG(Z-6),SUED(Z-6),NORD(31),Z-6,3,1] : Rem  Nordfeld
   Else
      RF=-1
      ERLAUBT[-1,1,NORD(31),RF,3,1] : Rem                  Nordrandfeld
      If OK=2 and AUS_STREET=0
         Pop Proc
      End If
   End If
   '
   If Z+6<31
      ERLAUBT[GESETZTFLAG(Z+6),NORD(Z+6),SUED(31),Z+6,1,3] : Rem  Suedfeld
   Else
      RF=-1
      ERLAUBT[-1,1,SUED(31),RF,1,3] : Rem                  Suedrandfeld
      If OK=2 and AUS_STREET=0
         Pop Proc
      End If
   End If
   '
   If Z=1 or Z=7 or Z=13 or Z=19 or Z=25
      RF=-1
      ERLAUBT[-1,1,WEST(31),RF,2,4] : Rem                  Westrandfeld
      If OK=2 and AUS_STREET=0
         Pop Proc
      End If
   Else
      ERLAUBT[GESETZTFLAG(Z-1),OST(Z-1),WEST(31),Z-1,2,4] : Rem westfeld
   End If
   '
   If Z=6 or Z=12 or Z=18 or Z=24 or Z=30
      RF=-1
      ERLAUBT[-1,1,OST(31),RF,4,2] : Rem                    Ostrandfeld
      If OK=2 and AUS_STREET=0
         Pop Proc
      End If
   Else
      ERLAUBT[GESETZTFLAG(Z+1),WEST(Z+1),OST(31),Z+1,4,2] : Rem ostfeld
   End If
   LOESEFLAG=0
   If GEHT=-1
      For I=1 To 4
         OFFEN(1,I)=OFFEN(1,I)+OFFEN(2,I)
      Next I
   End If
End Proc
'
Procedure ERLAUBT[WEG1,WEG2,WEG3,RF,WEGOFFEN,ANWEG]
   '
   ' --------------------- Erstes Feld:  Rand an Rand *******************
   If NUMMER=1 and WEG3<>-1 and RF=-1
      GEHT=-1
      RF=0
      OK=0
      Pop Proc
   End If
   ' ---------------------- NICHT in freie Felder legen ****************
   If WEG1=0 and AUS_STREET=0
      Inc KONTROLLZAEHLER
      If KONTROLLZAEHLER<4
         Pop Proc
      End If
      ' ------------------- Erstes Feld:  beliebig ins Freie ***********
      If NUMMER=1
         GEHT=-1
         Pop Proc
      End If
   End If
   '
   ' ---------------------- Weg passt an Weg ***************************
   If WEG1=-1 and WEG2=-1 and WEG3=-1 and AUS_STREET=0
      OFFEN(1,WEGOFFEN)=OFFEN(1,WEGOFFEN)-1
      OFFEN(2,ANWEG)=0
      OFFEN(3,WEGOFFEN)=1
      GEHT=-1
      Pop Proc
   End If
   '
   ' ---------------------- kein Weg passt an kein Weg *****************
   If WEG1=-1 and WEG2=1 and WEG3=1 and AUS_STREET=0
      Pop Proc
   End If
   '
   ' ---------------------- letztes Feld legen *************************
   If AUS_STREET=-1
      If WEG1=-1 and WEG2=-1 and WEG3=-1
         OFFEN(1,WEGOFFEN)=OFFEN(1,WEGOFFEN)-1
         OFFEN(2,ANWEG)=0
         Inc LOESEFLAG
      End If
      If WEG1=-1 and WEG2=1 and WEG3=1
         Inc LOESEFLAG
      End If
      If WEG1=0 and WEG3=1
         Inc LOESEFLAG
      End If
      If LOESEFLAG=4 and OFFEN(1,1)=0 and OFFEN(1,2)=0 and OFFEN(1,3)=0 and OFFEN(1,4)=0
         GEHT=-1
         AUS_STREET=0
         LEVEL=LEVEL+1
         GELOEST=-1
         LOESEFLAG=0
         OK=0
         Pop Proc
      Else
         OK=2
      End If
   End If
   If AUSSTREET=0
      OK=2
   End If
End Proc
'
Procedure WERT_GEBEN[Z]
   NORD(Z)=NORD(31)
   OST(Z)=OST(31)
   SUED(Z)=SUED(31)
   WEST(Z)=WEST(31)
End Proc
'
Procedure WERTE_ZURUECK[Z]
   NORD(Z)=0
   OST(Z)=0
   SUED(Z)=0
   WEST(Z)=0
   GESETZTFLAG(Z)=0
   KONTROLLZAEHLER=0
   OK=0
End Proc
'
Procedure LOESEN
   AUS_STREET=0
   For I=1 To 11
      LETZTE_ZAHL=LETZTE_ZAHL+ANZAHL(I)
      If I=11 and LETZTE_ZAHL=0
         AUS_STREET=-1
      End If
      If ANZAHL(I)>0
         Pop Proc
      End If
   Next I
End Proc
'
Procedure FELDER_LOESCHEN
   For I=1 To 31
      NORD(I)=0
      SUED(I)=0
      WEST(I)=0
      OST(I)=0
      GESETZTFLAG(I)=0
   Next I
   For I=1 To 4
      OFFEN(1,I)=0
   Next I
End Proc
'
Procedure ZULETZT_ERNEUT[ENTFERNT,STREET]
   Screen Swap : DRUECKEN[29,19,216,232,198,214]
   Screen Swap : DRUECKEN[29,19,216,232,198,214]
   Shoot
   Screen Swap : Wait Vbl : Bob Clear
   Bob Off NUMMER : Bob Draw
   Screen Swap : Wait Vbl : Bob Clear : Bob Draw
   If NUMMER>0
      NUMMER=NUMMER-1
   End If
   NORD(ENTFERNT)=0
   SUED(ENTFERNT)=0
   WEST(ENTFERNT)=0
   OST(ENTFERNT)=0
   GESETZTFLAG(ENTFERNT)=0
   ANZAHL(STREET)=ANZAHL(STREET)+1
   For I=1 To 4
      OFFEN(1,I)=OFFEN(1,I)+OFFEN(3,I)-OFFEN(2,I)
   Next I
   AUSGABE
   Screen Swap : DRUECKEN[19,29,216,232,198,214]
   Screen Swap : DRUECKEN[19,29,216,232,198,214]
End Proc
'
Procedure NOCHMAL_VON_VORN
   Screen Swap : DRUECKEN[29,19,234,274,198,214]
   Screen Swap : DRUECKEN[29,19,234,274,198,214]
   Shoot
   NEUER_VERSUCH
   Restore LEVEL*1
   EINLESEN
   Screen Swap : DRUECKEN[19,29,234,274,198,214]
   Screen Swap : DRUECKEN[19,29,234,274,198,214]
End Proc
'
Procedure PASSWORD
   Screen Swap : DRUECKEN[29,19,233,309,79,95]
   Screen Swap : DRUECKEN[29,19,233,309,79,95]
   '
   EINGABE
   EINGABE$=Param$
   LOSUNG[EINGABE$]
   DUMM=Param
   '
   Screen Swap : DRUECKEN[19,29,233,309,79,95]
   Screen Swap : DRUECKEN[19,29,233,309,79,95]
End Proc[DUMM]
'
Procedure EINGABE
   Ink 20
   Screen Swap : Bar 234,100 To 307,114
   Screen Swap : Bar 234,100 To 307,114
   Locate 29,13 : Ink 1
   Screen Swap : Draw 235,104 To 235,110 : Flash 1,"(007,10)(fa0,10)"
   Screen Swap : Draw 235,104 To 235,110 : Flash 1,"(007,10)(fa0,10)"
   Ink 3,20
   Clear Key
   SCHREIBEN=0
   A$=""
   EINGABE$=""
   Repeat
      WARTE:
      A$=Inkey$
      A$=Upper$(A$)
      If A$="" Then Goto WARTE
      If Asc(A$)<>13 and Asc(A$)<>8 and SCHREIBEN<8
         EINGABE$=EINGABE$+A$
         Inc SCHREIBEN
         If SCHREIBEN=8
            Bell
         End If
         P=231+(SCHREIBEN*8)
         Screen Swap : Text P,110,A$
         Screen Swap : Text P,110,A$
      End If
      Exit If A$=Chr$(13)
      If Asc(A$)=8 and SCHREIBEN>0
         Screen Swap : Text P,110," "
         Screen Swap : Text P,110," "
         Dec SCHREIBEN
         P=231+(SCHREIBEN*8)
         EINGABE$=Mid$(EINGABE$,0,SCHREIBEN)
      End If
   Until A$=Chr$(13)
   Ink 23
   Screen Swap : Bar 234,100 To 307,114
   Screen Swap : Bar 234,100 To 307,114
   Flash Off
   PASSEN=-1
End Proc[EINGABE$]
'
Procedure LOSUNG[EINGABE$]
   If PASSEN=0
      Restore LEVEL*1+500
      Read SCHLUESSEL$
   Else
      For I=501 To 501+(MENGE-1)
         Restore I*1
         Read SCHLUESSEL$,DUMMDUMM
         If SCHLUESSEL$=EINGABE$
            For I=1 To 11
               Ink 23
               Screen Swap : Wait Vbl : Bar -9+(19*I),220 To 4+(19*I),229
               Screen Swap : Wait Vbl : Bar -9+(19*I),220 To 4+(19*I),229
            Next I
            DUMMY=-1
            LEVEL=DUMMDUMM
            Goto STUFE
         End If
         If I=501+(MENGE-1)
            SCHLUESSEL$=" FALSCH "
         End If
      Next I
   End If
   STUFE:
   Ink 23
   Screen Swap : Bar 234,100 To 307,114
   Screen Swap : Bar 234,100 To 307,114
   Ink 2,23
   Screen Swap : Text 239,110,SCHLUESSEL$
   Screen Swap : Text 239,110,SCHLUESSEL$
   PASSEN=0
   501 Data "ANFAENGE",1
   502 Data "SYNONYME",2
   503 Data "INFERIOR",3
   504 Data "FILIGRAN",4
   505 Data "COQUILLE",5
   506 Data "MANDARIN",6
   507 Data "TRIPODIE",7
   508 Data "KATATHYM",8
   509 Data "EPISTASE",9
   510 Data "HARPYIEN",10
   511 Data "BELGNETS",11
   512 Data "POLYAMID",12
   513 Data "NAVICULA",13
   514 Data "GAYEMENT",14
   515 Data "OMELETTE",15
   516 Data "LECTURER",16
   517 Data "ZODIAKUS",17
   518 Data "IPSATION",18
   519 Data "VIGNETTE",19
   520 Data "RELAXANS",20
   521 Data "YOHIMBIN",21
   522 Data "DUCHESSE",22
   523 Data "JAKONETT",23
   524 Data "UNDATION",24
   525 Data "QUIRINAL",25
End Proc[DUMMY]
'
Procedure GRATULATION
   Pen 2 : Paper 26
   Screen Swap : Wait Vbl
   Locate 0,0 : Print "    Gl�ckwunsch!!  Vorz�glich gel�st    "
   Screen Swap : Wait Vbl
   Locate 0,0 : Print "    Gl�ckwunsch!!  Vorz�glich gel�st    "
   Wait 100
   Paper 26
   Screen Swap : Wait Vbl : Locate 0,0 : Print Space$(40)
   Screen Swap : Wait Vbl : Locate 0,0 : Print Space$(40)
End Proc
'
Procedure SICHERHEITSABFRAGE
   Screen Swap : DRUECKEN[29,19,276,309,198,214]
   Screen Swap : DRUECKEN[29,19,276,309,198,214]
   Screen Open 0,640,48,16,Hires
   Curs Off
   Fade 1,$0,$D07
   Shoot
   Reserve Zone 2
   X1$=Zone$("   JA   ",1)
   X2$=Zone$(" Zur�ck ",2)
   Locate 0,1
   Centre " Soll das Programm wirklich beendet werden "
   Locate 0,4
   Centre " ??????? "
   Locate 20,4
   Print Border$(X1$,1)
   Locate 52,4
   Print Border$(X2$,1)
   Repeat
      Z=Mouse Zone
   Until Z>0 and Mouse Key
   Reset Zone
   Screen Close 0
   Bell
   Screen Swap : DRUECKEN[19,29,276,309,198,214]
   Screen Swap : DRUECKEN[19,29,276,309,198,214]
End Proc[Z]
'
Procedure DRUECKEN[F1,F2,W1,W2,H1,H2]
   Ink F1
   Draw W1,H1 To W1,H2-1
   Draw W1,H1 To W2,H1
   Ink F2
   Draw W1,H2 To W2,H2
   Draw W2,H1+1 To W2,H2
End Proc
'
Procedure INFO
   Bell
   Screen Swap : DRUECKEN[29,19,233,309,174,190]
   Screen Swap : DRUECKEN[29,19,233,309,174,190]
   Screen Open 0,640,256,16,Hires : Fade 1,$0,$0
   Reserve Zone 1
   Cls 0 : Curs Off : Flash Off
   Colour 3,$FB2
   Pen 3 : Cmove ,3
   Print "KREUZWEG"; : Paper 0 : Print " ist ein kleines Logikspiel, in dem es darum geht, GESCHLOSSENE Systeme aus den vorgegebenen Wegteilen zu finden."
   Print : Print "Ich denke, die wenigen Funktionen erkl�ren sich von selbst, so da� ich mir hier die M�he sparen kann, sie einzeln zu erl�utern. Das gesamte Game hat 25 LEVEL,  die jedoch nie das ganze Spielfeld ausnutzen (max. 20 Felder)."
   Paper 6 : Cmove ,4
   Centre "Dieses Programm ist Freeware." : Cmove ,2
   Paper 0 : Centre "Es darf allerdings auf keiner Disk erscheinen, die teurer als 5,- DM ist."
   Cmove ,1 : Centre "Au�erdem d�rfen Name und Copyrightvermerk nicht entfernt werden."
   Cmove ,2 : Centre "Anregungen, Erweiterungen, Bug-Report senden an:"
   Cmove ,2 : Paper 6 : Centre " Delf Schl�ter, Siebenplaneten 24, 4630 BOCHUM 7 "
   Cmove ,1 : Centre " � 1992 in Bochum "
   Paper 14 : Cmove ,3 : Centre Border$(Zone$("ZUR�CK",1),2)
   Repeat
      Z=Mouse Zone
   Until Z=1 and Mouse Key
   Bell
   Reset Zone
   Screen Close 0
   Screen Swap : DRUECKEN[19,29,233,309,174,190]
   Screen Swap : DRUECKEN[19,29,233,309,174,190]
End Proc
'
'